216 lines
7.3 KiB
Bash
216 lines
7.3 KiB
Bash
#!/usr/bin/env zsh
|
|
# -*- mode: zsh; sh-indentation: 2; indent-tabs-mode: nil; sh-basic-offset: 2; -*-
|
|
# vim: ft=zsh sw=2 ts=2 et
|
|
|
|
# Copyleft 2011 zsh-syntax-highlighting contributors
|
|
# http://github.com/nicoulaj/zsh-syntax-highlighting
|
|
# All wrongs reserved.
|
|
|
|
# Token types styles.
|
|
typeset -gA ZSH_HIGHLIGHT_STYLES
|
|
ZSH_HIGHLIGHT_STYLES=(
|
|
default 'none'
|
|
isearch 'fg=magenta,standout'
|
|
special 'fg=magenta,standout'
|
|
unknown-token 'fg=red,bold'
|
|
reserved-word 'fg=yellow'
|
|
alias 'fg=green'
|
|
builtin 'fg=green'
|
|
function 'fg=green'
|
|
command 'fg=green'
|
|
path 'underline'
|
|
globbing 'fg=blue'
|
|
history-expansion 'fg=blue'
|
|
single-hyphen-option 'none'
|
|
double-hyphen-option 'none'
|
|
back-quoted-argument 'none'
|
|
single-quoted-argument 'fg=yellow'
|
|
double-quoted-argument 'fg=yellow'
|
|
dollar-double-quoted-argument 'fg=cyan'
|
|
back-double-quoted-argument 'fg=cyan'
|
|
bracket-error 'fg=red,bold'
|
|
)
|
|
|
|
# Tokens that are always followed by a command.
|
|
ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS=(
|
|
'|'
|
|
'||'
|
|
';'
|
|
'&'
|
|
'&&'
|
|
'sudo'
|
|
'start'
|
|
'time'
|
|
'strace'
|
|
'noglob'
|
|
'nocorrect'
|
|
'command'
|
|
'builtin'
|
|
'whence'
|
|
'which'
|
|
'where'
|
|
'whereis'
|
|
)
|
|
|
|
# Colors for bracket levels
|
|
# Put as many color as you wish
|
|
# Leave it as an empty array to disable
|
|
ZSH_MATCHING_BRACKETS=(
|
|
'fg=blue,bold'
|
|
'fg=green,bold'
|
|
'fg=magenta,bold'
|
|
'fg=yellow,bold'
|
|
'fg=cyan,bold'
|
|
)
|
|
|
|
# ZLE highlight types.
|
|
zle_highlight=(
|
|
special:$ZSH_HIGHLIGHT_STYLES[special]
|
|
isearch:$ZSH_HIGHLIGHT_STYLES[isearch]
|
|
)
|
|
|
|
# Check if the argument is a path.
|
|
_zsh_check-path() {
|
|
[[ -z $arg ]] && return 1
|
|
[[ -e $arg ]] && return 0
|
|
[[ ! -e ${arg:h} ]] && return 1
|
|
[[ ${#BUFFER} == $end_pos && -n $(print $arg*(N)) ]] && return 0
|
|
return 1
|
|
}
|
|
|
|
# Highlight special chars inside double-quoted strings
|
|
_zsh_highlight-string() {
|
|
setopt localoptions noksharrays
|
|
local i j k style
|
|
# Starting quote is at 1, so start parsing at offset 2 in the string.
|
|
for (( i = 2 ; i < end_pos - start_pos ; i += 1 )) ; do
|
|
(( j = i + start_pos - 1 ))
|
|
(( k = j + 1 ))
|
|
case "$arg[$i]" in
|
|
'$') style=$ZSH_HIGHLIGHT_STYLES[dollar-double-quoted-argument];;
|
|
"\\") style=$ZSH_HIGHLIGHT_STYLES[back-double-quoted-argument]
|
|
(( k += 1 )) # Color following char too.
|
|
(( i += 1 )) # Skip parsing the escaped char.
|
|
;;
|
|
*) continue;;
|
|
esac
|
|
region_highlight+=("$j $k $style")
|
|
done
|
|
}
|
|
|
|
# Recolorize the current ZLE buffer.
|
|
_zsh_highlight-zle-buffer() {
|
|
# Avoid doing the same work over and over
|
|
[[ ${ZSH_PRIOR_HIGHLIGHTED_BUFFER:-} == $BUFFER ]] && return
|
|
ZSH_PRIOR_HIGHLIGHTED_BUFFER=$BUFFER
|
|
|
|
setopt localoptions extendedglob bareglobqual
|
|
local new_expression=true
|
|
local start_pos=0
|
|
local highlight_glob=true
|
|
local end_pos arg style
|
|
region_highlight=()
|
|
for arg in ${(z)BUFFER}; do
|
|
local substr_color=0
|
|
[[ $start_pos -eq 0 && $arg = 'noglob' ]] && highlight_glob=false
|
|
((start_pos+=${#BUFFER[$start_pos+1,-1]}-${#${BUFFER[$start_pos+1,-1]##[[:space:]]#}}))
|
|
((end_pos=$start_pos+${#arg}))
|
|
if $new_expression; then
|
|
new_expression=false
|
|
res=$(LC_ALL=C builtin type -w $arg 2>/dev/null)
|
|
case $res in
|
|
*': reserved') style=$ZSH_HIGHLIGHT_STYLES[reserved-word];;
|
|
*': alias') style=$ZSH_HIGHLIGHT_STYLES[alias]
|
|
local aliased_command="${"$(alias $arg)"#*=}"
|
|
if [[ ${${ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS[(r)$aliased_command]:-}:+yes} = 'yes' && ${${ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS[(r)$arg]:-}:+yes} != 'yes' ]]; then
|
|
ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS+=($arg)
|
|
fi
|
|
;;
|
|
*': builtin') style=$ZSH_HIGHLIGHT_STYLES[builtin];;
|
|
*': function') style=$ZSH_HIGHLIGHT_STYLES[function];;
|
|
*': command') style=$ZSH_HIGHLIGHT_STYLES[command];;
|
|
*) if _zsh_check-path; then
|
|
style=$ZSH_HIGHLIGHT_STYLES[path]
|
|
elif [[ $arg[0,1] = $histchars[0,1] ]]; then
|
|
style=$ZSH_HIGHLIGHT_STYLES[history-expansion]
|
|
else
|
|
style=$ZSH_HIGHLIGHT_STYLES[unknown-token]
|
|
fi
|
|
;;
|
|
esac
|
|
else
|
|
case $arg in
|
|
'--'*) style=$ZSH_HIGHLIGHT_STYLES[double-hyphen-option];;
|
|
'-'*) style=$ZSH_HIGHLIGHT_STYLES[single-hyphen-option];;
|
|
"'"*"'") style=$ZSH_HIGHLIGHT_STYLES[single-quoted-argument];;
|
|
'"'*'"') style=$ZSH_HIGHLIGHT_STYLES[double-quoted-argument]
|
|
region_highlight+=("$start_pos $end_pos $style")
|
|
_zsh_highlight-string
|
|
substr_color=1
|
|
;;
|
|
'`'*'`') style=$ZSH_HIGHLIGHT_STYLES[back-quoted-argument];;
|
|
*"*"*) $highlight_glob && style=$ZSH_HIGHLIGHT_STYLES[globbing] || style=$ZSH_HIGHLIGHT_STYLES[default];;
|
|
*) if _zsh_check-path; then
|
|
style=$ZSH_HIGHLIGHT_STYLES[path]
|
|
elif [[ $arg[0,1] = $histchars[0,1] ]]; then
|
|
style=$ZSH_HIGHLIGHT_STYLES[history-expansion]
|
|
else
|
|
style=$ZSH_HIGHLIGHT_STYLES[default]
|
|
fi
|
|
;;
|
|
esac
|
|
fi
|
|
[[ $substr_color = 0 ]] && region_highlight+=("$start_pos $end_pos $style")
|
|
[[ ${${ZSH_HIGHLIGHT_TOKENS_FOLLOWED_BY_COMMANDS[(r)${arg//|/\|}]:-}:+yes} = 'yes' ]] && new_expression=true
|
|
start_pos=$end_pos
|
|
done
|
|
|
|
# Bracket matching
|
|
bracket_color_size=${#ZSH_MATCHING_BRACKETS}
|
|
if ((bracket_color_size > 0)); then
|
|
((level = 0))
|
|
for pos in {1..${#BUFFER}}; do
|
|
case $BUFFER[pos] in
|
|
"("|"["|"{")
|
|
((level++))
|
|
region_highlight+=("$((pos - 1)) $pos "$ZSH_MATCHING_BRACKETS[(( (level - 1) % bracket_color_size + 1 ))])
|
|
;;
|
|
")"|"]"|"}")
|
|
if ((level < 1)); then
|
|
region_highlight+=("$((pos - 1)) $pos "$ZSH_HIGHLIGHT_STYLES[bracket-error])
|
|
else
|
|
region_highlight+=("$((pos - 1)) $pos "$ZSH_MATCHING_BRACKETS[(( (level - 1) % bracket_color_size + 1 ))])
|
|
fi
|
|
((level--))
|
|
;;
|
|
esac
|
|
done
|
|
fi
|
|
}
|
|
|
|
# Special treatment for completion/expansion events:
|
|
# For each *complete* function (except 'accept-and-menu-complete'),
|
|
# we create a widget which mimics the original
|
|
# and use this orig-* version inside the new colorized zle function (the dot
|
|
# idiom used for all others doesn't work right for these functions for some
|
|
# reason). You can see the default setup using "zle -l -L".
|
|
|
|
# Bind all ZLE events from zle -la to highlighting function.
|
|
for f in $(zle -la); do
|
|
case $f in
|
|
.*|_*)
|
|
;;
|
|
accept-and-menu-complete)
|
|
eval "$f() { builtin zle .$f && _zsh_highlight-zle-buffer } ; zle -N $f"
|
|
;;
|
|
*complete*)
|
|
eval "zle -C orig-$f .$f _main_complete ; $f() { builtin zle orig-$f && _zsh_highlight-zle-buffer } ; zle -N $f"
|
|
;;
|
|
*)
|
|
eval "$f() { builtin zle .$f && _zsh_highlight-zle-buffer } ; zle -N $f"
|
|
;;
|
|
esac
|
|
done
|
|
|
|
|