#compdef gist
# ------------------------------------------------------------------------------
# Copyright (c) 2017 Github zsh-users - https://github.com/zsh-users
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#     * Redistributions of source code must retain the above copyright
#       notice, this list of conditions and the following disclaimer.
#     * Redistributions in binary form must reproduce the above copyright
#       notice, this list of conditions and the following disclaimer in the
#       documentation and/or other materials provided with the distribution.
#     * Neither the name of the zsh-users nor the
#       names of its contributors may be used to endorse or promote products
#       derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL ZSH-USERS BE LIABLE FOR ANY
# DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
# ------------------------------------------------------------------------------
# Description
# -----------
#
#  Completion script for gist (https://github.com/defunkt/gist)
#
# ------------------------------------------------------------------------------
# Authors
# -------
#
#  * Akira Maeda <https://github.com/glidenote>
#  * Patrick Ziegler <https://github.com/patrick96>
#  * Shivam Mehta <https://github.com/maniac-en>
#
# ------------------------------------------------------------------------------

_gist() {
  local ret=1

  _arguments \
    '(--login)--login[Authenticate gist on this computer.]' \
    '(-f --filename)'{-f,--filename}'[Sets the filename and syntax type.]:NAME' \
    '(-t --type)'{-t,--type}'[Sets the file extension and syntax type.]:EXT' \
    '(-p --private --no-private)'{-p,--private}'[Makes your gist private.]' \
    '(--no-private -p --private)--no-private[Makes your gist no private.]' \
    '(-d --description)'{-d,--description}'[Adds a description to your gist.]:DESCRIPTION' \
    '(-s --shorten)'{-s,--shorten}'[Shorten the gist URL using git.io.]' \
    '(-u --update)'{-u,--update}'[Update an existing gist.]:URL ID:_gist_ids' \
    '(-c --copy)'{-c,--copy}'[Copy the resulting URL to the clipboard]' \
    '(-e --embed)'{-e,--embed}'[Copy the embed code for the gist to the clipboard]' \
    '(-o --open --no-open)'{-o,--open}'[Open the resulting URL in a browser]' \
    '(--no-open -o --open)--no-open[No open the resulting URL in a browser]' \
    '--skip-empty[Skip gisting empty files]' \
    '(-P --paste)'{-P,--paste}'[Paste from the clipboard to gist]' \
    '(-R --raw)'{-R,--raw}'[Display raw URL of the new gist]' \
    '(-l --list)'{-l,--list}'[List all gists for user ]::user' \
    '--delete[Delete a gist]:id:_gist_ids' \
    '(- *)'{-h,--help}'[print options help]' \
    '(-v --version)'{-v,--version}'[print version]' \
    '(-r --read)'{-r,--read}'[Read a gist and print out the contents]:user gists:_gist_ids' \
    '*: :_files' && ret=0

  return ret
}

_gist_cache_policy() {
  # rebuild if cache is more than a day old
  local -a oldp
  oldp=( "$1"(m+1) )
  (( $#oldp ))
}

_gist_ids() {
  local update_policy ret=1
  zstyle -s ":completion:${curcontext}:" cache-policy update_policy
  if [[ -z "$update_policy" ]]; then
    zstyle ":completion:${curcontext}:" cache-policy _gist_cache_policy
  fi

  # stores the gists of the logged in user in the format ID[Description]
  local -a gist_list

  # retrieve/Write gists from/to cache
  if _cache_invalid gist_cached_list  || ! _retrieve_cache gist_cached_list; then
    if (( $+commands[ruby] )); then
      gist_list=(${(f)"$(gist -l | ruby -ne 'puts "#{$1}:#{$2}" if $_ =~ %r{/([^/ ]+)\s+(.+)}')"})
    elif (( $+commands[perl])); then
      gist_list=(${(f)"$(gist -l | perl -wln -e 'm{/([^/ ]+)\s+(.+)} and print qq($1:$2)')"})
    fi

    if [[ $? -eq 0 ]]; then
      _store_cache gist_cached_list gist_list
    else
      # some error occurred, the user is probably not logged in
      # set _gists to an empty string so that no completion is attempted
      gist_list=()
    fi
  fi

  if [[ $#gist_list ]]; then
    _describe -t gist_ids 'gist_ids' gist_list
  fi

  return ret
}

_gist "$@"

# Local Variables:
# mode: Shell-Script
# sh-indentation: 2
# indent-tabs-mode: nil
# sh-basic-offset: 2
# End:
# vim: ft=zsh sw=2 ts=2 et