#compdef augmatch
# ------------------------------------------------------------------------------
# Copyright (c) 2025 Github zsh-users - https://github.com/zsh-users
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
# * Redistributions of source code must retain the above copyright
# notice, this list of conditions and the following disclaimer.
# * Redistributions in binary form must reproduce the above copyright
# notice, this list of conditions and the following disclaimer in the
# documentation and/or other materials provided with the distribution.
# * Neither the name of the zsh-users nor the
# names of its contributors may be used to endorse or promote products
# derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL ZSH-USERS BE LIABLE FOR ANY
# DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
# ------------------------------------------------------------------------------
# Description
# -----------
#
# Completion script for augmatch 1.14.1 (https://augeas.net/)
#
# ------------------------------------------------------------------------------
# Authors
# -------
#
#  * Shohei Yoshida (https://github.com/syohex) <syohex@gmail.com>
#
# ------------------------------------------------------------------------------

_augmatch_lens() {
  local lenses=($(augtool --noload 'match /augeas/load/*/lens' | sed -e 's/.*@//'))
  _values lenses $lenses
}

_arguments \
  '(- *)'{-h,--help}'[show help message]' \
  '(-a --all)'{-a,--all}'[print all tree nodes, even ones without an associated value]' \
  '(-e --extract)'{-e,--extract}'[only print the parts of the tree that are matched with --match]' \
  \*{-I,--include=}'[add directory to the module loadpath]:dir:_files -/' \
  '(-l --lens)'{-l,--lens=}'[use lens for the given file]:lens:_augmatch_lens' \
  '(-L --print-lens)'{-L,--print-lens}'[print the name of lens]' \
  '(-m --match)'{-m,--match=}'[only print the parts of the tree that match]:expr' \
  '(-r --root)'{-r,--root=}'[use directory as the root of the filesystem]:dir:_files -/' \
  '(-S --nostdinc)'{-S,--nostdinc}'[do not search any of the default directories for lenses]' \
  '(-o --only-value)'{-o,--only-value}'[print only the value and not label or the path of nodes]' \
  '(-q --quiet)'{-q,--quiet}'[do not print anything]' \
  '*:: :_files'

# Local Variables:
# mode: Shell-Script
# sh-indentation: 2
# indent-tabs-mode: nil
# sh-basic-offset: 2
# End:
# vim: ft=zsh sw=2 ts=2 et