Merge 21de7e270c into 9253fb1c50

iTerm2 3.7.0 added receiver support for the OSC 133 k= attribute
(Semantic Prompt prompt kinds: k=i initial, k=s secondary/PS2,
k=c continuation, k=r right). When emitted by the shell, iTerm2
records the bracketed cells as non-input on the active primary
prompt mark, so consumers (Select Current Command, share-as-URL,
AI prompt extraction, the Python GetPromptResponse.excluded_subranges
field) can subtract them from the typed-command range.

Two gaps for iTerm2 today:

1. The RPROMPT k=r wrap in _p9k_init_prompt is gated to WarpTerminal.
   iTerm2 sessions never trip the gate, so right-prompt cells leak
   into "Select Current Command", share URLs, etc.

2. p10k replaces iTerm2's iterm2_decorate_prompt with a stub that
   only records ITERM2_PRECMD_PS1. iTerm2's original function also
   wraps PS2 with OSC 133; the stub drops that wrap entirely, so
   multi-line input (for, while, unclosed quotes, heredocs, backslash
   continuations) produces no k=s markers and iTerm2 has no way to
   tell PS2-prefix cells apart from user input.

Both fixes are gated on iTerm2 >= 3.7.0 via
TERM_PROGRAM_VERSION == (3.<7->*|<4->.*). Older iTerm2 receivers do
not parse k= and would treat k=r/k=s markers as spurious primary
prompts (extra navigation marks, broken command-range tracking,
broken paste-each-line semantics). WarpTerminal behavior is
unchanged. The ITERM2_SQUELCH_PS2_MARK opt-out from iTerm2's
original iterm2_decorate_prompt is preserved.

internal/p10k.zsh

@@ -138,6 +138,14 @@ function getColorCode() {
   return 1
 }
 
+function _p9k_codeset_is_utf8() {
+  # Use `case` to survive SH_GLOB.
+  case "${langinfo[CODESET]}" in
+    utf-8|UTF-8|utf8|UTF8) return 0;;
+    *) return 1;;
+  esac
+}
+
 # _p9k_declare <type> <uppercase-name> [default]...
 function _p9k_declare() {
   local -i set=$+parameters[$2]
@@ -1969,7 +1977,7 @@ prompt_dir() {
   if (( $+_POWERLEVEL9K_SHORTEN_DELIMITER )); then
     local delim=$_POWERLEVEL9K_SHORTEN_DELIMITER
   else
-    if [[ $langinfo[CODESET] == (utf|UTF)(-|)8 ]]; then
+    if _p9k_codeset_is_utf8; then
       local delim=$'\u2026'
     else
       local delim='..'
@@ -7020,13 +7028,13 @@ function _p9k_restore_special_params() {
 }
 
 function _p9k_on_expand() {
-  (( _p9k__expanded && ! ${+__p9k_instant_prompt_active} )) && [[ "${langinfo[CODESET]}" == (utf|UTF)(-|)8 ]] && return
+  (( _p9k__expanded && ! ${+__p9k_instant_prompt_active} )) && _p9k_codeset_is_utf8 && return
 
   eval "$__p9k_intro_no_locale"
 
-  if [[ $langinfo[CODESET] != (utf|UTF)(-|)8 ]]; then
+  if ! _p9k_codeset_is_utf8; then
     _p9k_restore_special_params
-    if [[ $langinfo[CODESET] != (utf|UTF)(-|)8 ]] && _p9k_init_locale; then
+    if ! _p9k_codeset_is_utf8 && _p9k_init_locale; then
       if [[ -n $LC_ALL ]]; then
         _p9k__real_lc_all=$LC_ALL
         LC_ALL=$__p9k_locale
@@ -7627,7 +7635,7 @@ _p9k_init_params() {
   _p9k_declare -i POWERLEVEL9K_VCS_SHORTEN_LENGTH
   _p9k_declare -i POWERLEVEL9K_VCS_SHORTEN_MIN_LENGTH
   _p9k_declare -s POWERLEVEL9K_VCS_SHORTEN_STRATEGY
-  if [[ $langinfo[CODESET] == (utf|UTF)(-|)8 ]]; then
+  if _p9k_codeset_is_utf8; then
     _p9k_declare -e POWERLEVEL9K_VCS_SHORTEN_DELIMITER '\u2026'
   else
     _p9k_declare -e POWERLEVEL9K_VCS_SHORTEN_DELIMITER '..'
@@ -8568,14 +8576,16 @@ _p9k_init_prompt() {
   if (( _POWERLEVEL9K_TERM_SHELL_INTEGRATION )); then
     _p9k_prompt_prefix_left+=$'%{\e]133;A\a%}'
     _p9k_prompt_suffix_left+=$'%{\e]133;B\a%}'
-    if [[ $TERM_PROGRAM == WarpTerminal ]]; then
+    if [[ $TERM_PROGRAM == WarpTerminal ||
+          ( $TERM_PROGRAM == iTerm.app && $TERM_PROGRAM_VERSION == (3.<7->*|<4->.*) ) ]]; then
       _p9k_prompt_prefix_right=$'%{\e]133;P;k=r\a%}'$_p9k_prompt_prefix_right
       _p9k_prompt_suffix_right+=$'%{\e]133;B\a%}'
     fi
     if (( $+_z4h_iterm_cmd && _z4h_can_save_restore_screen == 1 )); then
       _p9k_prompt_prefix_left+=$'%{\ePtmux;\e\e]133;A\a\e\\%}'
       _p9k_prompt_suffix_left+=$'%{\ePtmux;\e\e]133;B\a\e\\%}'
-      if [[ $TERM_PROGRAM == WarpTerminal ]]; then
+      if [[ $TERM_PROGRAM == WarpTerminal ||
+            ( $TERM_PROGRAM == iTerm.app && $TERM_PROGRAM_VERSION == (3.<7->*|<4->.*) ) ]]; then
         _p9k_prompt_prefix_right=$'%{\ePtmux;\e\e]133;P;k=r\a\e\\%}'$_p9k_prompt_prefix_right
         _p9k_prompt_suffix_right+=$'%{\ePtmux;\e\e]133;B\a\e\\%}'
       fi
@@ -9134,6 +9144,11 @@ _p9k_init() {
     function iterm2_decorate_prompt() {
       typeset -g ITERM2_PRECMD_PS1=$PROMPT
       typeset -g ITERM2_SHOULD_DECORATE_PROMPT=
+      if [[ -n $PS2 && $PS2 != *$'\e]133;A;k=s\a'* && -z ${ITERM2_SQUELCH_PS2_MARK-} &&
+            $TERM_PROGRAM_VERSION == (3.<7->*|<4->.*) ]]; then
+        typeset -g ITERM2_PRECMD_PS2=$PS2
+        PS2=$'%{\e]133;A;k=s\a%}'$PS2$'%{\e]133;B\a%}'
+      fi
     }
   fi
   if (( $+functions[iterm2_precmd] )); then
@@ -9681,7 +9696,7 @@ if [[ $__p9k_dump_file != $__p9k_instant_prompt_dump_file && -n $__p9k_instant_p
   zf_rm -f -- $__p9k_instant_prompt_dump_file{,.zwc} 2>/dev/null
 fi
 
-typeset -g P9K_VERSION=1.20.14
+typeset -g P9K_VERSION=1.20.17
 
 if [[ ${VSCODE_SHELL_INTEGRATION-} == <1-> && ${+__p9k_force_term_shell_integration} == 0 ]]; then
   typeset -gri __p9k_force_term_shell_integration=1

powerlevel10k.zsh-theme

@@ -27,7 +27,13 @@
   local -a match mbegin mend
   local -i MBEGIN MEND OPTIND
   local MATCH OPTARG IFS=$'\'' \t\n\0'\'
-  typeset -gr __p9k_intro_locale='[[ $langinfo[CODESET] != (utf|UTF)(-|)8 ]] && _p9k_init_locale && { [[ -n $LC_ALL ]] && local LC_ALL=$__p9k_locale || local LC_CTYPE=$__p9k_locale }'
+  # Use `case` to survive SH_GLOB.
+  typeset -gr __p9k_intro_locale='{
+    case "${langinfo[CODESET]}" in
+      utf-8|UTF-8|utf8|UTF8) false;;
+      *) true;;
+    esac
+  } && _p9k_init_locale && { [[ -n "$LC_ALL" ]] && local LC_ALL=$__p9k_locale || local LC_CTYPE=$__p9k_locale }'
   typeset -gr __p9k_intro_no_locale="${${__p9k_intro_base/ match / match reply }/ MATCH / MATCH REPLY }"
   typeset -gr __p9k_intro_no_reply="$__p9k_intro_base; $__p9k_intro_locale"
   typeset -gr __p9k_intro="$__p9k_intro_no_locale; $__p9k_intro_locale"