Merge 4d340d9e6d into 30e516a3aa

lib/cli.zsh

@@ -41,6 +41,7 @@ function _omz {
         refs=("${(@f)$(builtin cd -q "$ZSH"; command git for-each-ref --format="%(refname:short):%(subject)" refs/heads refs/tags)}")
         _describe 'command' refs ;;
       plugin) subcmds=(
+        'cat:Show plugin source'
         'disable:Disable plugin(s)'
         'enable:Enable plugin(s)'
         'info:Get plugin information'
@@ -203,6 +204,7 @@ Usage: ${(j: :)${(s.::.)0#_}} <command> [options]
 
 Available commands:
 
+  cat <plugin>     Show the source of a plugin
   disable <plugin> Disable plugin(s)
   enable <plugin>  Enable plugin(s)
   info <plugin>    Get information of a plugin
@@ -219,6 +221,42 @@ EOF
   $0::$command "$@"
 }
 
+function _omz::plugin::cat {
+  if [[ -z "$1" ]]; then
+    echo >&2 "Usage: ${(j: :)${(s.::.)0#_}} <plugin>"
+    return 1
+  fi
+
+  local plugin_source
+  for plugin_source in "$ZSH_CUSTOM/plugins/$1/$1.plugin.zsh" "$ZSH/plugins/$1/$1.plugin.zsh"; do
+    if [[ -f "$plugin_source" ]]; then
+      # If being piped, just cat the source
+      if [[ ! -t 1 ]]; then
+        cat "$plugin_source"
+        return $?
+      fi
+
+      # Enrich the source display depending on the tools we have
+      # - glow: https://github.com/charmbracelet/glow
+      # - bat: https://github.com/sharkdp/bat
+      # - less: typical pager command
+      case 1 in
+        ${+commands[glow]}) glow -p "$plugin_source" ;;
+        ${+commands[bat]}) bat -l zsh --style plain "$plugin_source" ;;
+        ${+commands[less]}) less "$plugin_source" ;;
+        *) cat "$readme" ;;
+      esac
+      return $?
+    fi
+  done
+
+  if [[ ! -d "$ZSH_CUSTOM/plugins/$1" && ! -d "$ZSH/plugins/$1" ]]; then
+    _omz::log error "'$1' plugin not found"
+  fi
+
+  return 1
+}
+
 function _omz::plugin::disable {
   if [[ -z "$1" ]]; then
     echo >&2 "Usage: ${(j: :)${(s.::.)0#_}} <plugin> [...]"

plugins/jj/README.md

@@ -0,0 +1,89 @@
+# jj - Jujutsu CLI
+
+This plugin provides autocompletion for [jj](https://martinvonz.github.io/jj).
+
+To use it, add `jj` to the plugins array of your zshrc file:
+
+```zsh
+plugins=(... jj)
+```
+
+## Aliases
+
+| Alias  | Command                       |
+| ------ | ----------------------------- |
+| jjc    | `jj commit`                   |
+| jjcmsg | `jj commit --message`         |
+| jjd    | `jj diff`                     |
+| jjdmsg | `jj desc --message`           |
+| jjds   | `jj desc`                     |
+| jje    | `jj edit`                     |
+| jjgcl  | `jj git clone`                |
+| jjgf   | `jj git fetch`                |
+| jjgp   | `jj git push`                 |
+| jjl    | `jj log`                      |
+| jjla   | `jj log -r "all()"`           |
+| jjn    | `jj new`                      |
+| jjrb   | `jj rebase`                   |
+| jjrs   | `jj restore`                  |
+| jjrt   | `cd "$(jj root \|\| echo .)"` |
+| jjsp   | `jj split`                    |
+| jjsq   | `jj squash`                   |
+
+## Prompt usage
+
+Because `jj` has a very powerful [template syntax](https://martinvonz.github.io/jj/latest/templates/), this
+plugin only exposes a convenience function `jj_prompt_template` to read information from the current change.
+It is basically the same as `jj log --no-graph -r @ -T $1`:
+
+```sh
+_my_theme_jj_info() {
+  jj_prompt_template 'self.change_id().shortest(3)'
+}
+
+PROMPT='$(_my_theme_jj_info) $'
+```
+
+`jj_prompt_template` escapes `%` signs in the output. Use `jj_prompt_template_raw` if you don't want that
+(e.g. to colorize the output).
+
+However, because `jj` can be used inside a Git repository, some themes might clash with it. Generally, you can
+fix it with a wrapper function that tries `jj` first and then falls back to `git` if it didn't work:
+
+```sh
+_my_theme_vcs_info() {
+  jj_prompt_template 'self.change_id().shortest(3)' \
+  || git_prompt_info
+}
+
+PROMPT='$(_my_theme_vcs_info) $'
+```
+
+You can find an example
+[here](https://github.com/nasso/omzsh/blob/e439e494f22f4fd4ef1b6cb64626255f4b341c1b/themes/sunakayu.zsh-theme).
+
+### Performance
+
+Sometimes `jj` can be slower than `git`.
+
+If you feel slowdowns, consider using the following:
+
+```
+zstyle :omz:plugins:jj ignore-working-copy yes
+```
+
+This will add `--ignore-working-copy` to all `jj` commands executed by your prompt. The downside here is that
+your prompt might be out-of-sync until the next time `jj` gets a chance to _not_ ignore the working copy (i.e.
+you manually run a `jj` command).
+
+If you prefer to keep your prompt always up-to-date but still don't want to _feel_ the slowdown, you can make
+your prompt asynchronous. This plugin doesn't do this automatically so you'd have to hack your theme a bit for
+that.
+
+## See Also
+
+- [martinvonz/jj](https://github.com/martinvonz/jj)
+
+## Contributors
+
+- [nasso](https://github.com/nasso) - Plugin Author

plugins/jj/jj.plugin.zsh

@@ -0,0 +1,53 @@
+# if jj is not found, don't do the rest of the script
+if (( ! $+commands[jj] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `jj`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_jj" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _jj
+  _comps[jj]=_jj
+fi
+
+jj util completion zsh >| "$ZSH_CACHE_DIR/completions/_jj" &|
+
+function __jj_prompt_jj() {
+  local -a flags
+  flags=("--no-pager")
+  if zstyle -t ':omz:plugins:jj' ignore-working-copy; then
+    flags+=("--ignore-working-copy")
+  fi
+  command jj $flags "$@"
+}
+
+# convenience functions for themes
+function jj_prompt_template_raw() {
+  __jj_prompt_jj log --no-graph -r @ -T "$@" 2> /dev/null
+}
+
+function jj_prompt_template() {
+  local out
+  out=$(jj_prompt_template_raw "$@") || return 1
+  echo "${out:gs/%/%%}"
+}
+
+# Aliases (sorted alphabetically)
+alias jjc='jj commit'
+alias jjcmsg='jj commit --message'
+alias jjd='jj diff'
+alias jjdmsg='jj desc --message'
+alias jjds='jj desc'
+alias jje='jj edit'
+alias jjgcl='jj git clone'
+alias jjgf='jj git fetch'
+alias jjgp='jj git push'
+alias jjl='jj log'
+alias jjla='jj log -r "all()"'
+alias jjn='jj new'
+alias jjrb='jj rebase'
+alias jjrs='jj restore'
+alias jjrt='cd "$(jj root || echo .)"'
+alias jjsp='jj split'
+alias jjsq='jj squash'