Merge 8924759b12 into 30e516a3aa

Add new setting `ZSH_FNM_AUTOSTART` to be able to automatic setup the `fnm env`.
Default set to `false` to avoid breaking existing setup.

plugins/fnm/README.md

@@ -2,8 +2,30 @@
 
 This plugin adds autocompletion for [fnm](https://github.com/Schniz/fnm) - a Node.js version manager.
 
-To use it, add `fnm` to the plugins array in your zshrc file:
+To use it, add `fnm` to the plugins array in your `.zshrc` file:
 
 ```zsh
 plugins=(... fnm)
 ```
+
+## Configuration Variables
+
+These settings should go in your `.zshrc` file, before Oh My Zsh is sourced.
+
+For example:
+
+```sh
+ZSH_FNM_AUTOSTART=true
+...
+plugins=(... fnm)
+source "$ZSH/oh-my-zsh.sh"
+```
+
+The following variables are available to this plugin customization:
+
+| Variable | Default | Meaning |
+| :------- | :-----: | ------- |
+| `ZSH_FNM_AUTOSTART` | `false` | Automatically starts fnm for the session, running the `fnm env` |
+| `ZSH_FNM_USE_ON_CD` | `true` | Switch the Node.js version based on the requirements of the current directory (recommended) |
+
+Check out the [official documentation](https://github.com/Schniz/fnm/blob/master/docs/commands.md) for the available fnm variables.

plugins/fnm/fnm.plugin.zsh

@@ -2,6 +2,11 @@ if (( ! $+commands[fnm] )); then
   return
 fi
 
+# CONFIGURATION VARIABLES
+# Automatically start the fnm multishell
+: ${ZSH_FNM_AUTOSTART:=false} # opt-in to avoid duplicated sessions
+: ${ZSH_FNM_USE_ON_CD:=true} # upstream recommendation
+
 # If the completion file doesn't exist yet, we need to autoload it and
 # bind it to `fnm`. Otherwise, compinit will have already done that.
 if [[ ! -f "$ZSH_CACHE_DIR/completions/_fnm" ]]; then
@@ -11,3 +16,9 @@ if [[ ! -f "$ZSH_CACHE_DIR/completions/_fnm" ]]; then
 fi
 
 fnm completions --shell=zsh >| "$ZSH_CACHE_DIR/completions/_fnm" &|
+
+if [[ "$ZSH_FNM_AUTOSTART" == "true" ]]; then
+  local -a fnm_env_cmd
+  [[ "$ZSH_FNM_USE_ON_CD" == "true" ]] && fnm_env_cmd+=("--use-on-cd")
+  eval "$(fnm env --shell=zsh $fnm_env_cmd)"
+fi

plugins/jj/README.md

@@ -0,0 +1,89 @@
+# jj - Jujutsu CLI
+
+This plugin provides autocompletion for [jj](https://martinvonz.github.io/jj).
+
+To use it, add `jj` to the plugins array of your zshrc file:
+
+```zsh
+plugins=(... jj)
+```
+
+## Aliases
+
+| Alias  | Command                       |
+| ------ | ----------------------------- |
+| jjc    | `jj commit`                   |
+| jjcmsg | `jj commit --message`         |
+| jjd    | `jj diff`                     |
+| jjdmsg | `jj desc --message`           |
+| jjds   | `jj desc`                     |
+| jje    | `jj edit`                     |
+| jjgcl  | `jj git clone`                |
+| jjgf   | `jj git fetch`                |
+| jjgp   | `jj git push`                 |
+| jjl    | `jj log`                      |
+| jjla   | `jj log -r "all()"`           |
+| jjn    | `jj new`                      |
+| jjrb   | `jj rebase`                   |
+| jjrs   | `jj restore`                  |
+| jjrt   | `cd "$(jj root \|\| echo .)"` |
+| jjsp   | `jj split`                    |
+| jjsq   | `jj squash`                   |
+
+## Prompt usage
+
+Because `jj` has a very powerful [template syntax](https://martinvonz.github.io/jj/latest/templates/), this
+plugin only exposes a convenience function `jj_prompt_template` to read information from the current change.
+It is basically the same as `jj log --no-graph -r @ -T $1`:
+
+```sh
+_my_theme_jj_info() {
+  jj_prompt_template 'self.change_id().shortest(3)'
+}
+
+PROMPT='$(_my_theme_jj_info) $'
+```
+
+`jj_prompt_template` escapes `%` signs in the output. Use `jj_prompt_template_raw` if you don't want that
+(e.g. to colorize the output).
+
+However, because `jj` can be used inside a Git repository, some themes might clash with it. Generally, you can
+fix it with a wrapper function that tries `jj` first and then falls back to `git` if it didn't work:
+
+```sh
+_my_theme_vcs_info() {
+  jj_prompt_template 'self.change_id().shortest(3)' \
+  || git_prompt_info
+}
+
+PROMPT='$(_my_theme_vcs_info) $'
+```
+
+You can find an example
+[here](https://github.com/nasso/omzsh/blob/e439e494f22f4fd4ef1b6cb64626255f4b341c1b/themes/sunakayu.zsh-theme).
+
+### Performance
+
+Sometimes `jj` can be slower than `git`.
+
+If you feel slowdowns, consider using the following:
+
+```
+zstyle :omz:plugins:jj ignore-working-copy yes
+```
+
+This will add `--ignore-working-copy` to all `jj` commands executed by your prompt. The downside here is that
+your prompt might be out-of-sync until the next time `jj` gets a chance to _not_ ignore the working copy (i.e.
+you manually run a `jj` command).
+
+If you prefer to keep your prompt always up-to-date but still don't want to _feel_ the slowdown, you can make
+your prompt asynchronous. This plugin doesn't do this automatically so you'd have to hack your theme a bit for
+that.
+
+## See Also
+
+- [martinvonz/jj](https://github.com/martinvonz/jj)
+
+## Contributors
+
+- [nasso](https://github.com/nasso) - Plugin Author

plugins/jj/jj.plugin.zsh

@@ -0,0 +1,53 @@
+# if jj is not found, don't do the rest of the script
+if (( ! $+commands[jj] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `jj`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_jj" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _jj
+  _comps[jj]=_jj
+fi
+
+jj util completion zsh >| "$ZSH_CACHE_DIR/completions/_jj" &|
+
+function __jj_prompt_jj() {
+  local -a flags
+  flags=("--no-pager")
+  if zstyle -t ':omz:plugins:jj' ignore-working-copy; then
+    flags+=("--ignore-working-copy")
+  fi
+  command jj $flags "$@"
+}
+
+# convenience functions for themes
+function jj_prompt_template_raw() {
+  __jj_prompt_jj log --no-graph -r @ -T "$@" 2> /dev/null
+}
+
+function jj_prompt_template() {
+  local out
+  out=$(jj_prompt_template_raw "$@") || return 1
+  echo "${out:gs/%/%%}"
+}
+
+# Aliases (sorted alphabetically)
+alias jjc='jj commit'
+alias jjcmsg='jj commit --message'
+alias jjd='jj diff'
+alias jjdmsg='jj desc --message'
+alias jjds='jj desc'
+alias jje='jj edit'
+alias jjgcl='jj git clone'
+alias jjgf='jj git fetch'
+alias jjgp='jj git push'
+alias jjl='jj log'
+alias jjla='jj log -r "all()"'
+alias jjn='jj new'
+alias jjrb='jj rebase'
+alias jjrs='jj restore'
+alias jjrt='cd "$(jj root || echo .)"'
+alias jjsp='jj split'
+alias jjsq='jj squash'