Merge ba824c8fd2 into 30e516a3aa

plugins/dep/README.md

@@ -0,0 +1,20 @@
+# Dep plugin
+
+This plugin adds completion for the [Dep - Dependency management for Go](https://golang.github.io/dep/),
+as well as some aliases for common Dep commands.
+
+To use it, add `dep` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... dep)
+```
+
+## Aliases
+
+| Alias | Command                                   | Description                                                                                                   |
+|-------|-------------------------------------------|---------------------------------------------------------------------------------------------------------------|
+| depc  | `dep check`                               | Check if imports, `Gopkg.toml`, and `Gopkg.lock` are in sync                                                  |
+| deps  | `dep status`                              | Report the status of the project dependencies                                                                 |
+| depe  | `dep ensure`                              | Ensure a dependency is safely vendored in the project                                                         |
+| depa  | `dep ensure -add`                         | Add new dependencies, or populate `Gopkg.toml` with constraints for existing dependencies                     |
+| depu  | `dep ensure -update`                      | update the named dependencies (or all, if none are named) in Gopkg.lock to the latest allowed by `Gopkg.toml` |

plugins/dep/_dep

@@ -0,0 +1,66 @@
+#compdef dep
+#autoload
+
+# dep zsh completion, based on last release 0.5.2
+# Sagi Medina <sagimedina@gmail.com>
+
+local -a _1st_arguments
+_1st_arguments=(
+  'init:Set up a new Go project, or migrate an existing one'
+  'status:Report the status of the project dependencies'
+  'ensure:Ensure a dependency is safely vendored in the project'
+  'version:Show the dep version information'
+  'check:Check if imports, Gopkg.toml, and Gopkg.lock are in sync'
+)
+
+local expl
+local -a all_pkgs installed_pkgs
+
+_arguments \
+  '(-h --help)'{-h,--help}'[output usage information]' \
+  '*:: :->subcmds' && return 0
+
+if (( CURRENT == 1 )); then
+  _describe -t commands "dep subcommand" _1st_arguments
+  return
+fi
+
+case "$words[1]" in
+  init)
+    _arguments \
+      '(-gopath)'-gopath'[search in GOPATH for dependencies (default: false)]' \
+      '(-no-examples)'-no-examples'[dont include example in Gopkg.toml (default: false)]' \
+      '(-skip-tools)'-skip-tools'[skip importing configuration from other dependency managers (default: false)]' \
+      '(-v)'-v'[enable verbose logging (default: false)]' ;;
+  status)
+    _arguments \
+      '(-detail)'-detail'[include more detail in the chosen format (default: false)]' \
+      '(-dot)'-dot'[output the dependency graph in GraphViz format (default: false)]' \
+      '(-examples)'-examples'[print detailed usage examples (default: false)]' \
+      '(-f)'-f'[output in text/template format (default: <none>)]' \
+      '(-json)'-json'[output in JSON format (default: false)]' \
+      '(-lock)'-lock'[output in the lock file format (assumes -detail) (default: false)]' \
+      '(-missing)'-missing'[only show missing dependencies (default: false)]' \
+      '(-old)'-old'[only show out-of-date dependencies (default: false)]' \
+      '(-out)'-out'[path to a file to which to write the output. Blank value will be ignored (default: <none>)]' \
+      '(-v)'-v'[enable verbose logging (default: false)]' \
+      '1: :->packages' &&  return 0 ;;
+  ensure)
+    _arguments \
+      '(-add)'-add'[add new dependencies, or populate Gopkg.toml with constraints for existing dependencies (default: false)]' \
+      '(-dry-run)'-dry-run'[only report the changes that would be made (default: false)]' \
+      '(-examples)'-examples'[print detailed usage examples (default: false)]' \
+      '(-no-vendor)'-no-vendor'[update Gopkg.lock (if needed), but do not update vendor/ (default: false)]' \
+      '(-update)'-update'[update the named dependencies (or all, if none are named) in Gopkg.lock to the latest allowed by Gopkg.toml (default: false)]' \
+      '(-v)'-v'[enable verbose logging (default: false)]' \
+      '(-vendor-only)'-vendor-only'[populate vendor/ from Gopkg.lock without updating it first (default: false)]' \
+      '1: :->packages' &&  return 0 ;;
+  version)
+    _arguments \
+      '(-v)'-v'[enable verbose logging (default: false)]' ;;
+  check)
+    _arguments \
+      '(-q)'-q'[Suppress non-error output (default: false)]' \
+      '(-skip-lock)'-skip-lock'[Skip checking that imports and Gopkg.toml are in sync with Gopkg.lock (default: false)]' \
+      '(-skip-vendor)'-skip-vendor'[Skip checking that vendor is in sync with Gopkg.lock (default: false)]' ;;
+esac

plugins/dep/dep.plugin.zsh

@@ -0,0 +1,5 @@
+alias depc="dep check"
+alias deps="dep status"
+alias depe="dep ensure"
+alias depa="dep ensure -add"
+alias depu="dep ensure -update"

plugins/jj/README.md

@@ -0,0 +1,89 @@
+# jj - Jujutsu CLI
+
+This plugin provides autocompletion for [jj](https://martinvonz.github.io/jj).
+
+To use it, add `jj` to the plugins array of your zshrc file:
+
+```zsh
+plugins=(... jj)
+```
+
+## Aliases
+
+| Alias  | Command                       |
+| ------ | ----------------------------- |
+| jjc    | `jj commit`                   |
+| jjcmsg | `jj commit --message`         |
+| jjd    | `jj diff`                     |
+| jjdmsg | `jj desc --message`           |
+| jjds   | `jj desc`                     |
+| jje    | `jj edit`                     |
+| jjgcl  | `jj git clone`                |
+| jjgf   | `jj git fetch`                |
+| jjgp   | `jj git push`                 |
+| jjl    | `jj log`                      |
+| jjla   | `jj log -r "all()"`           |
+| jjn    | `jj new`                      |
+| jjrb   | `jj rebase`                   |
+| jjrs   | `jj restore`                  |
+| jjrt   | `cd "$(jj root \|\| echo .)"` |
+| jjsp   | `jj split`                    |
+| jjsq   | `jj squash`                   |
+
+## Prompt usage
+
+Because `jj` has a very powerful [template syntax](https://martinvonz.github.io/jj/latest/templates/), this
+plugin only exposes a convenience function `jj_prompt_template` to read information from the current change.
+It is basically the same as `jj log --no-graph -r @ -T $1`:
+
+```sh
+_my_theme_jj_info() {
+  jj_prompt_template 'self.change_id().shortest(3)'
+}
+
+PROMPT='$(_my_theme_jj_info) $'
+```
+
+`jj_prompt_template` escapes `%` signs in the output. Use `jj_prompt_template_raw` if you don't want that
+(e.g. to colorize the output).
+
+However, because `jj` can be used inside a Git repository, some themes might clash with it. Generally, you can
+fix it with a wrapper function that tries `jj` first and then falls back to `git` if it didn't work:
+
+```sh
+_my_theme_vcs_info() {
+  jj_prompt_template 'self.change_id().shortest(3)' \
+  || git_prompt_info
+}
+
+PROMPT='$(_my_theme_vcs_info) $'
+```
+
+You can find an example
+[here](https://github.com/nasso/omzsh/blob/e439e494f22f4fd4ef1b6cb64626255f4b341c1b/themes/sunakayu.zsh-theme).
+
+### Performance
+
+Sometimes `jj` can be slower than `git`.
+
+If you feel slowdowns, consider using the following:
+
+```
+zstyle :omz:plugins:jj ignore-working-copy yes
+```
+
+This will add `--ignore-working-copy` to all `jj` commands executed by your prompt. The downside here is that
+your prompt might be out-of-sync until the next time `jj` gets a chance to _not_ ignore the working copy (i.e.
+you manually run a `jj` command).
+
+If you prefer to keep your prompt always up-to-date but still don't want to _feel_ the slowdown, you can make
+your prompt asynchronous. This plugin doesn't do this automatically so you'd have to hack your theme a bit for
+that.
+
+## See Also
+
+- [martinvonz/jj](https://github.com/martinvonz/jj)
+
+## Contributors
+
+- [nasso](https://github.com/nasso) - Plugin Author

plugins/jj/jj.plugin.zsh

@@ -0,0 +1,53 @@
+# if jj is not found, don't do the rest of the script
+if (( ! $+commands[jj] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `jj`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_jj" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _jj
+  _comps[jj]=_jj
+fi
+
+jj util completion zsh >| "$ZSH_CACHE_DIR/completions/_jj" &|
+
+function __jj_prompt_jj() {
+  local -a flags
+  flags=("--no-pager")
+  if zstyle -t ':omz:plugins:jj' ignore-working-copy; then
+    flags+=("--ignore-working-copy")
+  fi
+  command jj $flags "$@"
+}
+
+# convenience functions for themes
+function jj_prompt_template_raw() {
+  __jj_prompt_jj log --no-graph -r @ -T "$@" 2> /dev/null
+}
+
+function jj_prompt_template() {
+  local out
+  out=$(jj_prompt_template_raw "$@") || return 1
+  echo "${out:gs/%/%%}"
+}
+
+# Aliases (sorted alphabetically)
+alias jjc='jj commit'
+alias jjcmsg='jj commit --message'
+alias jjd='jj diff'
+alias jjdmsg='jj desc --message'
+alias jjds='jj desc'
+alias jje='jj edit'
+alias jjgcl='jj git clone'
+alias jjgf='jj git fetch'
+alias jjgp='jj git push'
+alias jjl='jj log'
+alias jjla='jj log -r "all()"'
+alias jjn='jj new'
+alias jjrb='jj rebase'
+alias jjrs='jj restore'
+alias jjrt='cd "$(jj root || echo .)"'
+alias jjsp='jj split'
+alias jjsq='jj squash'