Merge 01808b3aae into 30e516a3aa

Automatic "Oh My ZSH" installation when adding new users

plugins/adduser/README.md

@@ -0,0 +1,26 @@
+# adduser
+
+This plugin adds support for installing "Oh My ZSH" when adding new users.
+
+To use it, add `adduser` to the plugins array of your `~/.zshrc` file:
+
+```zsh
+plugins=(... adduser)
+```
+
+## Usage
+
+Just run `adduser` as you normally would do and now:
+
+1. The regular `adduser` command will run.
+2. The shell of the new user will switch to zsh
+3. "Oh My zsh will be installed (as if he would have ran `install.sh` himself).
+
+## NOTES
+
+- It is assumed that the last argument will be the username.<br>*(In rare cases people provide the group as last argument)*
+- `useradd` behaviour is not changed.
+
+## Author
+
+[Nikolas Garofil](https://github.com/ngaro)

plugins/adduser/adduser.plugin.zsh

@@ -0,0 +1,70 @@
+# Copyright (c) 2021 Nikolas Garofil
+
+_adduser_result() {
+	local result_string="Installation of 'Oh My Zsh' for '$new_user'"
+
+	#Erase the temporary copy of the installscript when necessary
+	if [[ ! -z $temp_installscript  ]] ; then
+		rm $temp_installscript
+	fi
+
+	#mention the result
+	if [[ $1 -eq 0 ]]; then
+		echo "$result_string succeeded."
+	else
+		echo "$result_string failed." > /dev/stderr
+	fi
+
+}
+
+adduser() {
+	local path_installscript="$ZSH/tools/install.sh"
+	local unattended_options=" --unattended"
+
+	local new_user=${@[$#]}
+	local temp_installscript; local unattended_installer; local install_as_user; local change_shell;
+
+	#Create user, errors will be reported by the 'real' adduser
+	#Don't use $new_user so that we have all args
+	command adduser $@ || return 1
+
+	echo "\nUser '$new_user' has been created. I will now try to install 'Oh My Zsh'"
+
+	if [[ ! -f $path_installscript ]] ; then
+		echo "Installationscript '$path_installscript' not available" > /dev/stderr;
+		_adduser_result 1
+		return 1;
+	fi
+
+	#copy install.sh to a new file in temp that we can give the right owner to execute
+	#and also make sure that after the install script we are no longer the new user
+	temp_installscript=$(mktemp)
+	cp $path_installscript $temp_installscript
+	chown $new_user $temp_installscript && chmod +x $temp_installscript
+	unattended_installer="$temp_installscript $unattended_options"
+
+	if [[ ( ! -x "$commands[sudo]" ) && ( ! -x "$commands[su]" )  ]] ; then
+		echo "You can't become $new_user (no 'sudo' or 'su' available)" > /dev/stderr;
+		_adduser_result 1
+		return 1;
+	fi
+	if [[ -x "$commands[sudo]" ]] ; then
+		install_as_user="sudo -u $new_user sh -c '$unattended_installer'"
+		change_shell="sudo chsh -s $commands[zsh] $new_user"
+	else
+		install_as_user="su -l $new_user -c '$unattended_installer'"
+		change_shell="su -c 'chsh -s $commands[zsh] $new_user'"
+	fi
+
+	eval ${install_as_user}
+	#mention the result before changing the shell (even with a bad result it's still installed)
+	if [ ! $? -eq 0 ] ; then
+		_adduser_result 1
+		return 1
+	fi
+
+	if [[ ! -x "$commands[chsh]" ]] ; then
+		echo "'chsh' is not available, change the shell manually." > /dev/stderr
+	fi
+	eval ${change_shell}
+}

plugins/jj/README.md

@@ -0,0 +1,89 @@
+# jj - Jujutsu CLI
+
+This plugin provides autocompletion for [jj](https://martinvonz.github.io/jj).
+
+To use it, add `jj` to the plugins array of your zshrc file:
+
+```zsh
+plugins=(... jj)
+```
+
+## Aliases
+
+| Alias  | Command                       |
+| ------ | ----------------------------- |
+| jjc    | `jj commit`                   |
+| jjcmsg | `jj commit --message`         |
+| jjd    | `jj diff`                     |
+| jjdmsg | `jj desc --message`           |
+| jjds   | `jj desc`                     |
+| jje    | `jj edit`                     |
+| jjgcl  | `jj git clone`                |
+| jjgf   | `jj git fetch`                |
+| jjgp   | `jj git push`                 |
+| jjl    | `jj log`                      |
+| jjla   | `jj log -r "all()"`           |
+| jjn    | `jj new`                      |
+| jjrb   | `jj rebase`                   |
+| jjrs   | `jj restore`                  |
+| jjrt   | `cd "$(jj root \|\| echo .)"` |
+| jjsp   | `jj split`                    |
+| jjsq   | `jj squash`                   |
+
+## Prompt usage
+
+Because `jj` has a very powerful [template syntax](https://martinvonz.github.io/jj/latest/templates/), this
+plugin only exposes a convenience function `jj_prompt_template` to read information from the current change.
+It is basically the same as `jj log --no-graph -r @ -T $1`:
+
+```sh
+_my_theme_jj_info() {
+  jj_prompt_template 'self.change_id().shortest(3)'
+}
+
+PROMPT='$(_my_theme_jj_info) $'
+```
+
+`jj_prompt_template` escapes `%` signs in the output. Use `jj_prompt_template_raw` if you don't want that
+(e.g. to colorize the output).
+
+However, because `jj` can be used inside a Git repository, some themes might clash with it. Generally, you can
+fix it with a wrapper function that tries `jj` first and then falls back to `git` if it didn't work:
+
+```sh
+_my_theme_vcs_info() {
+  jj_prompt_template 'self.change_id().shortest(3)' \
+  || git_prompt_info
+}
+
+PROMPT='$(_my_theme_vcs_info) $'
+```
+
+You can find an example
+[here](https://github.com/nasso/omzsh/blob/e439e494f22f4fd4ef1b6cb64626255f4b341c1b/themes/sunakayu.zsh-theme).
+
+### Performance
+
+Sometimes `jj` can be slower than `git`.
+
+If you feel slowdowns, consider using the following:
+
+```
+zstyle :omz:plugins:jj ignore-working-copy yes
+```
+
+This will add `--ignore-working-copy` to all `jj` commands executed by your prompt. The downside here is that
+your prompt might be out-of-sync until the next time `jj` gets a chance to _not_ ignore the working copy (i.e.
+you manually run a `jj` command).
+
+If you prefer to keep your prompt always up-to-date but still don't want to _feel_ the slowdown, you can make
+your prompt asynchronous. This plugin doesn't do this automatically so you'd have to hack your theme a bit for
+that.
+
+## See Also
+
+- [martinvonz/jj](https://github.com/martinvonz/jj)
+
+## Contributors
+
+- [nasso](https://github.com/nasso) - Plugin Author

plugins/jj/jj.plugin.zsh

@@ -0,0 +1,53 @@
+# if jj is not found, don't do the rest of the script
+if (( ! $+commands[jj] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `jj`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_jj" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _jj
+  _comps[jj]=_jj
+fi
+
+jj util completion zsh >| "$ZSH_CACHE_DIR/completions/_jj" &|
+
+function __jj_prompt_jj() {
+  local -a flags
+  flags=("--no-pager")
+  if zstyle -t ':omz:plugins:jj' ignore-working-copy; then
+    flags+=("--ignore-working-copy")
+  fi
+  command jj $flags "$@"
+}
+
+# convenience functions for themes
+function jj_prompt_template_raw() {
+  __jj_prompt_jj log --no-graph -r @ -T "$@" 2> /dev/null
+}
+
+function jj_prompt_template() {
+  local out
+  out=$(jj_prompt_template_raw "$@") || return 1
+  echo "${out:gs/%/%%}"
+}
+
+# Aliases (sorted alphabetically)
+alias jjc='jj commit'
+alias jjcmsg='jj commit --message'
+alias jjd='jj diff'
+alias jjdmsg='jj desc --message'
+alias jjds='jj desc'
+alias jje='jj edit'
+alias jjgcl='jj git clone'
+alias jjgf='jj git fetch'
+alias jjgp='jj git push'
+alias jjl='jj log'
+alias jjla='jj log -r "all()"'
+alias jjn='jj new'
+alias jjrb='jj rebase'
+alias jjrs='jj restore'
+alias jjrt='cd "$(jj root || echo .)"'
+alias jjsp='jj split'
+alias jjsq='jj squash'