Merge 0b8a9d1de2 into 30e516a3aa

This patch adds the git library function for building a
short string that represents the output of git diff --numstat.
This gives theme designers the ability to add the
Number of files changed, number of lines added and number of
lines removed in their prompt for a git repository, while the user's
current working directory is in the git repo.

The new function supports prefix and suffix for each of the
options, files changed, lines added and lines removed.

To colorize the output, you can do something like this in your
theme file

ZSH_THEME_GIT_FILES_CHANGED_PREFIX="%{$fg[yellow]%}"
ZSH_THEME_GIT_FILES_CHANGED_SUFFIX="%{$reset_color%}"
ZSH_THEME_GIT_LINES_ADDED_PREFIX="%{$fg[green]%}"
ZSH_THEME_GIT_LINES_ADDED_SUFFIX="%{$reset_color%}"
ZSH_THEME_GIT_LINES_REMOVED_PREFIX="%{$fg[red]%}"
ZSH_THEME_GIT_LINES_REMOVED_SUFFIX="%{$fg[blue]%}"

For example, if there are
3 files changed, 10 lines added and no lines removed you will get
3f:10+

1 files changed, 20 lines added and 6 lines removed:
1f:20+:6-

lib/git.zsh

@@ -365,3 +365,34 @@ function git_repo_name() {
     echo ${repo_path:t}
   fi
 }
+
+# Outputs 3 stats for git repo
+# 1) number of files changed,
+# 2) the total number of lines added
+# 3) total number of lines removed
+# 
+# Example 
+#  3f:69+:6-
+function git_files_changed() {
+    local -i files=0
+    local -i insertions=0
+    local -i deletions=0
+    local raw=$(command git diff --numstat 2>/dev/null) || return 0
+    if [[ -n $raw ]]; then
+      echo $raw | while IFS= read -r line; do
+        local -i d=$line[(w)2]
+        local -i i=$line[(w)1]
+        insertions+=i
+        deletions+=d
+        files+=1
+      done
+      local output="$ZSH_THEME_GIT_FILES_CHANGED_PREFIX${files}f$ZSH_THEME_GIT_FILES_CHANGED_SUFFIX"
+      if (( $insertions > 0 )); then
+          output="$output:$ZSH_THEME_GIT_LINES_ADDED_PREFIX${insertions}+$ZSH_THEME_GIT_LINES_ADDED_SUFFIX"
+      fi
+      if (( $deletions > 0 )); then
+          output="$output:$ZSH_THEME_GIT_LINES_REMOVED_PREFIX${deletions}-$ZSH_THEME_GIT_LINES_REMOVED_SUFFIX"
+      fi
+      echo $output
+    fi
+}

plugins/jj/README.md

@@ -0,0 +1,89 @@
+# jj - Jujutsu CLI
+
+This plugin provides autocompletion for [jj](https://martinvonz.github.io/jj).
+
+To use it, add `jj` to the plugins array of your zshrc file:
+
+```zsh
+plugins=(... jj)
+```
+
+## Aliases
+
+| Alias  | Command                       |
+| ------ | ----------------------------- |
+| jjc    | `jj commit`                   |
+| jjcmsg | `jj commit --message`         |
+| jjd    | `jj diff`                     |
+| jjdmsg | `jj desc --message`           |
+| jjds   | `jj desc`                     |
+| jje    | `jj edit`                     |
+| jjgcl  | `jj git clone`                |
+| jjgf   | `jj git fetch`                |
+| jjgp   | `jj git push`                 |
+| jjl    | `jj log`                      |
+| jjla   | `jj log -r "all()"`           |
+| jjn    | `jj new`                      |
+| jjrb   | `jj rebase`                   |
+| jjrs   | `jj restore`                  |
+| jjrt   | `cd "$(jj root \|\| echo .)"` |
+| jjsp   | `jj split`                    |
+| jjsq   | `jj squash`                   |
+
+## Prompt usage
+
+Because `jj` has a very powerful [template syntax](https://martinvonz.github.io/jj/latest/templates/), this
+plugin only exposes a convenience function `jj_prompt_template` to read information from the current change.
+It is basically the same as `jj log --no-graph -r @ -T $1`:
+
+```sh
+_my_theme_jj_info() {
+  jj_prompt_template 'self.change_id().shortest(3)'
+}
+
+PROMPT='$(_my_theme_jj_info) $'
+```
+
+`jj_prompt_template` escapes `%` signs in the output. Use `jj_prompt_template_raw` if you don't want that
+(e.g. to colorize the output).
+
+However, because `jj` can be used inside a Git repository, some themes might clash with it. Generally, you can
+fix it with a wrapper function that tries `jj` first and then falls back to `git` if it didn't work:
+
+```sh
+_my_theme_vcs_info() {
+  jj_prompt_template 'self.change_id().shortest(3)' \
+  || git_prompt_info
+}
+
+PROMPT='$(_my_theme_vcs_info) $'
+```
+
+You can find an example
+[here](https://github.com/nasso/omzsh/blob/e439e494f22f4fd4ef1b6cb64626255f4b341c1b/themes/sunakayu.zsh-theme).
+
+### Performance
+
+Sometimes `jj` can be slower than `git`.
+
+If you feel slowdowns, consider using the following:
+
+```
+zstyle :omz:plugins:jj ignore-working-copy yes
+```
+
+This will add `--ignore-working-copy` to all `jj` commands executed by your prompt. The downside here is that
+your prompt might be out-of-sync until the next time `jj` gets a chance to _not_ ignore the working copy (i.e.
+you manually run a `jj` command).
+
+If you prefer to keep your prompt always up-to-date but still don't want to _feel_ the slowdown, you can make
+your prompt asynchronous. This plugin doesn't do this automatically so you'd have to hack your theme a bit for
+that.
+
+## See Also
+
+- [martinvonz/jj](https://github.com/martinvonz/jj)
+
+## Contributors
+
+- [nasso](https://github.com/nasso) - Plugin Author

plugins/jj/jj.plugin.zsh

@@ -0,0 +1,53 @@
+# if jj is not found, don't do the rest of the script
+if (( ! $+commands[jj] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `jj`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_jj" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _jj
+  _comps[jj]=_jj
+fi
+
+jj util completion zsh >| "$ZSH_CACHE_DIR/completions/_jj" &|
+
+function __jj_prompt_jj() {
+  local -a flags
+  flags=("--no-pager")
+  if zstyle -t ':omz:plugins:jj' ignore-working-copy; then
+    flags+=("--ignore-working-copy")
+  fi
+  command jj $flags "$@"
+}
+
+# convenience functions for themes
+function jj_prompt_template_raw() {
+  __jj_prompt_jj log --no-graph -r @ -T "$@" 2> /dev/null
+}
+
+function jj_prompt_template() {
+  local out
+  out=$(jj_prompt_template_raw "$@") || return 1
+  echo "${out:gs/%/%%}"
+}
+
+# Aliases (sorted alphabetically)
+alias jjc='jj commit'
+alias jjcmsg='jj commit --message'
+alias jjd='jj diff'
+alias jjdmsg='jj desc --message'
+alias jjds='jj desc'
+alias jje='jj edit'
+alias jjgcl='jj git clone'
+alias jjgf='jj git fetch'
+alias jjgp='jj git push'
+alias jjl='jj log'
+alias jjla='jj log -r "all()"'
+alias jjn='jj new'
+alias jjrb='jj rebase'
+alias jjrs='jj restore'
+alias jjrt='cd "$(jj root || echo .)"'
+alias jjsp='jj split'
+alias jjsq='jj squash'